Процедура SetFTime

Модуль WinDos

Устанавливает атрибуты даты и времени у заданного файла.

Объявление:

Procedure SetFTime(Var F; Time : Longint);

Режим:

Protected,  Real

Замечание:

Коды ошибок передаются в переменную DosError. Единственный возможный код ошибки - 6 (Недопустимый дескриптор файла). Переменной F должно быть назначено имя и файл должен быть открыт.

Пример:

{GetFTime.PAS}
 
 { Пример программы для процедур GetFTime, PackTime, SetFTime и UnpackTime }
 
 Uses WinDos;
 
 Var          F : Text;
  H, M, S, Hund : Word; { Для GetTime}
          FTime : Longint; { для Get/SetFTime}
             Dt : TDateTime; { Для Pack/UnpackTime}
 
 Function LeadingZero(W : Word) : String;
 Var S : String;
 Begin
  Str(W:0, S);
  If Length(S) = 1 Then S:='0'+S;
  LeadingZero:=S;
 End;
 
 Begin
  Assign(F, 'TEST.TXT');
  GetTime(H, M, S, Hund);
  ReWrite(F); { Создаем новый файл }
  GetFTime(F, FTime); { Получаем дату создания }
  WriteLn('Файл создан в ', LeadingZero(H), ':',
                            LeadingZero(M), ':', LeadingZero(S));
  UnpackTime(FTime, Dt);
  With Dt Do
   Begin
    WriteLn('Атрибут времени файла ', LeadingZero(Hour), ':',
               LeadingZero(Min), ':', LeadingZero(Sec));
    Hour:=0;
    Min:=1;
    Sec:=0;
    PackTime(Dt, Ftime);
    WriteLn('Атрибут времени файла установлен на 00:01:00');
    Reset(F); { Открываем файл на чтение }
              { (Вызов Close обновит атрибут времени) }
    SetFTime(F, FTime);
   End;
  Close(F);   { Закрываем файл }
 End.